it-roy-ru.com

VBScript для создания запланированного задания

Я пытаюсь создать VBScript, который создает пакетный файл, а затем создает запланированное задание для запуска пакетного файла. Пока что все, что я пробовал, создает командный файл, но не создает запланированное задание, и я не получил никаких ошибок. Вот что у меня так далеко:

Option Explicit

Dim objFSO, outFile, wShell
Set objFSO = CreateObject("Scripting.FileSystemObject")

Set outFile = objFSO.CreateTextFile("C:\test.bat", True)
outFile.WriteLine "Start www.google.com"
outFile.Close

Set wShell = CreateObject ("Wscript.Shell") 
wShell.Run "cmd SchTasks /Create /SC WEEKLY /D MON,TUE,WED,THU,FRI /TN 'Test Task' /TR 'C:\test.bat' /ST 16:30", 0

Я пробовал ""Test Task"" и ""C:\test.bat"", и получил те же результаты. Но когда я запускаю следующую команду в командной строке:

SchTasks /Create /SC WEEKLY /D MON,TUE,WED,THU,FRI /TN "Test Task" /TR "C:\test.bat" /ST 16:30

Задача успешно создана. 

Другой способ, которым я попытался это сделать, - создать 2 пакетных файла: один пакетный файл для открытия веб-страницы и один пакетный файл для создания запланированной задачи. Затем я закончил с запуском файла task.bat в конце. Вот что у меня было для этого:

Option Explicit

Dim objFSO, outFile, wShell
Set objFSO = CreateObject("Scripting.FileSystemObject")

Set outFile = objFSO.CreateTextFile("C:\test.bat", True)
outFile.WriteLine "Start www.google.com"
outFile.Close

Set outFile = objFSO.CreateTextFile("C:\task.bat", True)
outFile.WriteLine "SchTasks /Create /SC WEEKLY /D MON,TUE,WED,THU,FRI /TN ""Test Task"" /TR ""C:\test.bat"" /ST 16:30"

Set wShell = CreateObject ("Wscript.Shell") 
wShell.Run "cmd start ""C:\task.bat"""

Это создало командные файлы, но просто открыло cmd в конце и ничего не сделало после этого.

Я предполагаю, что проблема заключается в части wShell.Run, но я не достаточно опытен, чтобы понять, в чем проблема.

Я не уверен, куда идти отсюда, поэтому любые предложения будут отличными.

6
takeitback

Там нет необходимости для cmd. Schtasks - это собственный исполняемый файл, а не команда внутри cmd. А для ваших цитируемых параметров просто используйте две кавычки.

Например:

wShell.Run "SchTasks /Create /SC WEEKLY /D MON,TUE,WED,THU,FRI /TN ""Test Task"" /TR ""C:\test.bat"" /ST 16:30", 0
4
Bond

Как VBScript вы можете делать все, что может команда.

Вот как перечислить запланированные задачи в корневой папке.

Set TS = CreateObject("Schedule.Service")
TS.Connect("Serenity")

Set rootFolder = TS.GetFolder("\")

Set tasks = rootFolder.GetTasks(0)

If tasks.Count = 0 Then 
    Wscript.Echo "No tasks are registered."
Else
    WScript.Echo "Number of tasks registered: " & tasks.Count

    For Each Task In Tasks
    A=Task.Name
    A = A & " " & Task.NextRunTime
    A = A & " " & Task.LastTaskResult
    wscript.echo A
    Next
End If

Это из документации показывает, как создать задачу.

Пример запуска по времени (создание сценариев)

В этом примере сценария показано, как создать задачу, которая запускает Блокнот в определенное время. Задача содержит основанный на времени триггер, который задает начальную границу для активации задачи, исполняемое действие, запускающее Блокнот, и конечную границу, которая деактивирует задачу.

Следующая процедура описывает, как запланировать задачу для запуска исполняемого файла в определенное время.

Чтобы запланировать запуск блокнота в определенное время

  1. Создайте объект TaskService. Этот объект позволяет вам создать задачу в указанной папке. 

  2. Получить папку задач и создать задачу. Используйте метод TaskService.GetFolder, чтобы получить папку, в которой хранится задача, и метод TaskService.NewTask, чтобы создать объект TaskDefinition, который представляет задачу. 

  3. Определите информацию о задаче, используя объект TaskDefinition. Используйте свойство TaskDefinition.Settings, чтобы определить параметры, которые определяют, как служба Task Scheduler выполняет задачу, и свойство TaskDefinition.RegistrationInfo, чтобы определить информацию, которая описывает задачу.
  4. Создайте основанный на времени триггер, используя свойство TaskDefinition.Triggers. Это свойство обеспечивает доступ к объекту TriggerCollection. Используйте метод TriggerCollection.Create (определяющий тип триггера, который вы хотите создать), чтобы создать основанный на времени триггер. При создании триггера установите начальную и конечную границы триггера, чтобы активировать и деактивировать триггер. Начальная граница указывает, когда будет выполнено действие задачи. 
  5. Создайте действие для выполнения задачи с помощью свойства TaskDefinition.Actions. Это свойство обеспечивает доступ к объекту ActionCollection. Используйте метод ActionCollection.Create, чтобы указать тип действия, которое вы хотите создать. В этом примере используется объект ExecAction, представляющий действие, выполняющее операцию командной строки. 
  6. Зарегистрируйте задачу, используя метод TaskFolder.RegisterTaskDefinition. Для этого примера задача запустит Блокнот в текущее время плюс 30 секунд. 

В следующем примере VBScript показано, как запланировать выполнение задачи «Блокнот» через 30 секунд после регистрации задачи.

' This sample schedules a task to start notepad.exe 30 seconds
' from the time the task is registered.
'------------------------------------------------------------------

' A constant that specifies a time-based trigger.
const TriggerTypeTime = 1
' A constant that specifies an executable action.
const ActionTypeExec = 0   

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start notepad at a certain time"
regInfo.Author = "Administrator"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False

'********************************************************
' Create a time-based trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeTime)

' Trigger variables that define when the trigger is active.
Dim startTime, endTime

Dim time
time = DateAdd("s", 30, Now)  'start time = 30 seconds from now
startTime = XmlTime(time)

time = DateAdd("n", 5, Now) 'end time = 5 minutes from now
endTime = XmlTime(time)

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    'Five minutes
trigger.Id = "TimeTriggerId"
trigger.Enabled = True

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test TimeTrigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

'------------------------------------------------------------------
' Used to get the time for the trigger 
' startBoundary and endBoundary.
' Return the time in the correct format: 
' YYYY-MM-DDTHH:MM:SS. 
'------------------------------------------------------------------
Function XmlTime(t)
    Dim cSecond, cMinute, CHour, cDay, cMonth, cYear
    Dim tTime, tDate

    cSecond = "0" & Second(t)
    cMinute = "0" & Minute(t)
    cHour = "0" & Hour(t)
    cDay = "0" & Day(t)
    cMonth = "0" & Month(t)
    cYear = Year(t)

    tTime = Right(cHour, 2) & ":" & Right(cMinute, 2) & _
        ":" & Right(cSecond, 2)
    tDate = cYear & "-" & Right(cMonth, 2) & "-" & Right(cDay, 2)
    XmlTime = tDate & "T" & tTime 
End Function
6
bill

В сценарии вы использовали одинарные кавычки в команде, а в своем тесте в CMD вы использовали двойные кавычки. Это все еще работает, если вы бежите ..?:

SchTasks /Create /SC WEEKLY /D MON,TUE,WED,THU,FRI /TN 'Test Task' /TR 'C:\test.bat' /ST 16:30

Если нет, попробуйте двойные кавычки и избегайте их, удваивая их:

wShell.Run "SchTasks /Create /SC WEEKLY /D MON,TUE,WED,THU,FRI /TN ""Test Task"" /TR ""C:\test.bat"" /ST 16:30", 0
1
GolezTrol