it-roy-ru.com

Как мне объявить глобальную переменную в VBA?

Я написал следующий код:

Function find_results_idle()

    Public iRaw As Integer
    Public iColumn As Integer
    iRaw = 1
    iColumn = 1

И я получаю сообщение об ошибке:

"недопустимый атрибут в Sub или Function"

Вы знаете, что я сделал не так?

Я попытался использовать Global вместо Public, но получил ту же проблему.

Я пытался объявить саму функцию `Public, но это также не помогло.

Что мне нужно сделать, чтобы создать глобальную переменную?

113
Nimrod

Вам нужно объявить переменные вне функции:

Public iRaw As Integer
Public iColumn As Integer

Function find_results_idle()
    iRaw = 1
    iColumn = 1
159
SLaks

Это вопрос о scope .

Если вы хотите, чтобы переменные сохранялись в течение всего времени жизни функции, используйте Dim (сокращение от Dimension) внутри функции или подпрограммы, чтобы объявить переменные:

Function AddSomeNumbers() As Integer
    Dim intA As Integer
    Dim intB As Integer
    intA = 2
    intB = 3
    AddSomeNumbers = intA + intB
End Function
'intA and intB are no longer available since the function ended

Переменная global (как указывал SLaks) объявляется вне функции с помощью ключевого слова Public. Эта переменная будет доступна в течение срока службы вашего запущенного приложения. В случае с Excel это означает, что переменные будут доступны, пока эта конкретная книга Excel открыта.

Public intA As Integer
Private intB As Integer

Function AddSomeNumbers() As Integer
    intA = 2
    intB = 3
    AddSomeNumbers = intA + intB
End Function
'intA and intB are still both available.  However, because intA is public,  '
'it can also be referenced from code in other modules. Because intB is private,'
'it will be hidden from other modules.

Вы также можете иметь переменные, которые доступны только в определенном модуле (или классе), объявив их с ключевым словом Private.

Если вы создаете большое приложение и чувствуете необходимость использовать глобальные переменные, я бы порекомендовал создать отдельный модуль только для ваших глобальных переменных. Это должно помочь вам отслеживать их в одном месте.

107
Ben McCormack

Чтобы использовать глобальные переменные, вставьте новый модуль из пользовательского интерфейса проекта VBA и объявите переменные с помощью Global

Global iRaw As Integer
Global iColumn As Integer
32
YOU

Вопрос действительно о размахе, как сказал другой парень.

Вкратце рассмотрим этот «модуль»:

Public Var1 As variant     'Var1 can be used in all
                           'modules, class modules and userforms of 
                           'thisworkbook and will preserve any values
                           'assigned to it until either the workbook
                           'is closed or the project is reset.

Dim Var2 As Variant        'Var2 and Var3 can be used anywhere on the
Private Var3 As Variant    ''current module and will preserve any values
                           ''they're assigned until either the workbook
                           ''is closed or the project is reset.

Sub MySub()                'Var4 can only be used within the procedure MySub
    Dim Var4 as Variant    ''and will only store values until the procedure 
End Sub                    ''ends.

Sub MyOtherSub()           'You can even declare another Var4 within a
    Dim Var4 as Variant    ''different procedure without generating an
End Sub                    ''error (only possible confusion). 

Вы можете проверить это ссылка на MSDN для получения дополнительной информации об объявлении переменных и этот другой вопрос переполнения стека для получения дополнительной информации о том, как переменные выходят за рамки.

Две другие быстрые вещи:

  1. Будьте организованы при использовании переменных уровня книги, чтобы ваш код не запутался. Предпочитайте Functions (с правильными типами данных) или передавая аргументы ByRef.
  2. Если вы хотите, чтобы переменная сохраняла свое значение между вызовами, вы можете использовать оператор Static.
14
FCastro

Если эта функция находится в модуле/классе, вы можете просто написать их вне функции, поэтому она имеет Global Scope. Глобальная область действия означает, что переменная может быть доступна другой функции в том же модуле/классе (если вы используете dim в качестве оператора объявления, используйте public, если вы хотите, чтобы переменные были доступны для всех функций во всех модулях):

Dim iRaw As Integer
Dim iColumn As Integer

Function find_results_idle()
    iRaw = 1
    iColumn = 1
End Function

Function this_can_access_global()
    iRaw = 2
    iColumn = 2
End Function
13
Zai

Создать публичное целое число в общей декларации.

Затем в вашей функции вы можете увеличивать ее значение каждый раз . См. Пример (функция для сохранения вложений электронной почты как CSV).

Public Numerator As Integer

Public Sub saveAttachtoDisk(itm As Outlook.MailItem)
Dim objAtt As Outlook.Attachment
Dim saveFolder As String
Dim FileName As String

saveFolder = "c:\temp\"

     For Each objAtt In itm.Attachments
            FileName = objAtt.DisplayName & "_" & Numerator & "_" & Format(Now, "yyyy-mm-dd H-mm-ss") & ".CSV"
                      objAtt.SaveAsFile saveFolder & "\" & FileName
                      Numerator = Numerator + 1

          Set objAtt = Nothing
     Next
End Sub
1
Dan Bidner

Хороший способ создания переменных Public/Global - это обрабатывать форму как объект класса, объявлять свойства и использовать открытое свойство Get [variable] для доступа к свойству/методу. Также вам может понадобиться сослаться на ссылку или передать ссылку на инстанцированный модуль Form. Вы получите ошибки, если будете вызывать методы для закрытых форм/отчетов.
Пример: передать Me.Form.Module.Parent в sub/function, а не внутри формы. 

Option Compare Database 
Option Explicit
''***********************************''
' Name: Date: Created Date Author: Name 
' Current Version: 1.0
' Called by: 
''***********************************''
' Notes: Explain Who what when why... 
' This code Example requires properties to be filled in 
''***********************************''
' Global Variables
Public GlobalData As Variant
''***********************************''
' Private Variables
Private ObjectReference As Object
Private ExampleVariable As Variant
Private ExampleData As Variant
''***********************************''
' Public properties
Public Property Get ObjectVariable() As Object
   Set ObjectVariable = ObjectReference
End Property 
Public Property Get Variable1() As Variant 
  'Recommend using variants to avoid data errors
  Variable1 = ExampleVariable
End property
''***********************************''
' Public Functions that return values
Public Function DataReturn (Input As Variant) As Variant
   DataReturn = ExampleData + Input
End Function 
''***********************************''
' Public Sub Routines
Public Sub GlobalMethod() 
   'call local Functions/Subs outside of form
   Me.Form.Refresh
End Sub
''***********************************''
' Private Functions/Subs used not visible outside 
''***********************************''
End Code

Таким образом, в другом модуле вы сможете получить доступ к: 

Public Sub Method1(objForm as Object)
   'read/write data value
   objForm.GlobalData
   'Get object reference (need to add Public Property Set to change reference object)
   objForm.ObjectVariable
   'read only (needs Public property Let to change value)
   objForm.Variable1
   'Gets result of function with input
   objForm.DataReturn([Input])
   'runs sub/function from outside of normal scope
   objForm.GlobalMethod
End Sub

Если вы используете Late Binding, как я, всегда проверяйте нулевые значения и объекты, которые являются Nothing, прежде чем пытаться выполнить какую-либо обработку. 

0
Double E CPU

Также вы можете использовать -

Private Const SrlNumber As Integer = 910

Private Sub Workbook_Open()
    If SrlNumber > 900 Then
        MsgBox "This serial number is valid"
    Else
        MsgBox "This serial number is not valid"
    End If
End Sub

Проверено на офис 2010

0
SftAps