it-roy-ru.com

PL/SQL: ошибка "PLS-00306: неверный номер или типы аргументов в вызове", запущенные для таблицы номеров

Я пытаюсь вызвать API, используя точную сигнатуру процедуры, но почему-то таблица чисел, которую я не считаю, распознается правильно.

Определение API:

TYPE NUMLIST IS TABLE OF NUMBER INDEX BY VARCHAR2(50);

PROCEDURE GETSERVICES_API
(
   I_DIMOBJID IN NUMBER, I_OBJECTID IN NUMBER, I_FILTER IN NUMBER, 
   O_ERRORCODE OUT NUMBER, O_ERRORTEXT OUT VARCHAR2, O_SERVICELIST OUT NUMLIST
);

Мой вызов API:

DECLARE

   TYPE NUMLIST IS TABLE OF NUMBER INDEX BY VARCHAR2(50);
   lt_SERVICELIST              NUMLIST;

   ls_errortext             varchar2(100);
   ln_errorcode             number;

BEGIN


    PKGCOMSUPPORT_SERVICE.GETSERVICES_API(I_DIMOBJID => 6,
                                          I_OBJECTID => 5263,
                                          I_FILTER => 3,
                                          O_ERRORCODE => ln_errorcode,
                                          O_ERRORTEXT => ls_errortext,
                                          O_SERVICELIST => lt_SERVICELIST);

END;

Когда я запускаю свой вызов API, я получаю: PLS-00306: неверное количество типов аргументов при вызове 'GETSERVICE_API

Есть идеи почему? Спасибо

8
Alin

Причиной возникновения ошибки PLS-00306 является несовместимость типа коллекции NUMLIST, определенного в спецификации пакета, и типа коллекции NUMLIST, определенного в анонимном блоке PL/SQL. Хотя определения этих двух типов коллекций совпадают, они не совместимы. В вашем анонимном PL/SQL-блоке вы должны объявить, а затем передать в процедуру GETSERVICES_API переменную типа данных PKGCOMSUPPORT_SERVICE.NUMLIST.

create or replace package PKG as
  type t_numlist is table of number index by varchar2(50);
  procedure SomeProc(p_var in pkg.t_numlist);
end;
/

create or replace package body PKG as
  procedure someproc(p_var in pkg.t_numlist) is
  begin
    null;
  end;
end;
/

declare
  type t_numlist is table of number index by varchar2(50);
  l_var t_numlist;
begin
  pkg.someproc(l_var);
end;

ORA-06550: line 5, column 3:
PLS-00306: wrong number or types of arguments in call to 'SOMEPROC'

declare
  --type t_numlist is table of number index by varchar2(50);
  l_var pkg.t_numlist;
begin
  pkg.someproc(l_var);
end;

anonymous block completed
9
Nick Krasnov

может быть, вы можете попробовать это:

CREATE TYPE NUMLIST AS TABLE OF NUMBER INDEX BY VARCHAR2(50);

DECLARE

   lt_SERVICELIST              NUMLIST;

   ls_errortext             varchar2(100);
   ln_errorcode             number;

BEGIN


    PKGCOMSUPPORT_SERVICE.GETSERVICES_API(I_DIMOBJID => 6,
                                          I_OBJECTID => 5263,
                                          I_FILTER => 3,
                                          O_ERRORCODE => ln_errorcode,
                                          O_ERRORTEXT => ls_errortext,
                                          O_SERVICELIST => lt_SERVICELIST);

END;
0
mucio

Я думаю, что определение типа недопустимо. Чтобы создать таблицу типа, вам нужно что-то вроде следующего:

CREATE OR REPLACE TYPE NUMLIST AS OBJECT (COLUMN1 VARCHAR2(50));
0
Andrew Cruickshank