it-roy-ru.com

Цикл каждой строки диапазона в Excel

Это одна из тех вещей, для которых, я уверен, есть встроенная функция (и мне, возможно, уже говорили об этом в прошлом), но я ломаю голову, чтобы вспомнить об этом.

Как мне пройти по каждой строке диапазона из нескольких столбцов, используя Excel VBA? Кажется, что все учебники, которые я искал, упоминают про работу в одномерном диапазоне ...

101
Margaret
Dim a As Range, b As Range

Set a = Selection

For Each b In a.Rows
    MsgBox b.Address
Next
137
Mike

Что-то вроде этого:

Dim rng As Range
Dim row As Range
Dim cell As Range

Set rng = Range("A1:C2")

For Each row In rng.Rows
  For Each cell in row.Cells
    'Do Something
  Next cell
Next row
134
David Andres

В Loops я всегда предпочитаю использовать класс Cells, используя ссылочный метод R1C1, например так:

Cells(rr, col).Formula = ...

Это позволяет мне быстро и легко цикл по диапазону ячеек легко:

Dim r As Long
Dim c As Long

c = GetTargetColumn() ' Or you could just set this manually, like: c = 1

With Sheet1 ' <-- You should always qualify a range with a sheet!

    For r = 1 To 10 ' Or 1 To (Ubound(MyListOfStuff) + 1)

        ' Here we're looping over all the cells in rows 1 to 10, in Column "c"
        .Cells(r, c).Value = MyListOfStuff(r)

        '---- or ----

        '...to easily copy from one place to another (even with an offset of rows and columns)
        .Cells(r, c).Value = Sheet2.Cells(r + 3, 17).Value


    Next r

End With
6
LimaNightHawk

Просто наткнулся на это и подумал, что предложу свое решение. Мне обычно нравится использовать встроенную функциональность назначения диапазона для многодимного массива (я думаю, это также и JS Programmer во мне).

Я часто пишу такой код:

Sub arrayBuilder()

myarray = Range("A1:D4")

'unlike most VBA Arrays, this array doesn't need to be declared and will be automatically dimensioned

For i = 1 To UBound(myarray)

    For j = 1 To UBound(myarray, 2)

    Debug.Print (myarray(i, j))

    Next j

Next i

End Sub

Присвоение диапазонов переменным является очень мощным способом манипулирования данными в VBA.

6
tc_NYC